//---------------------------- Fig. 2.6-2 #for
#version 3.7
global_settings
{assumed_gamma 2.2}
#include "colors.inc"
#include "textures.inc"
camera{
location<5,7,15>
sky<0,0,1>
right <-image_width/image_height,0,0>
look_at<1,1,0>
}
light_source{<50,-20,70> color White*1.2
parallel point_at 0}
//============================== #for loop
#for (i,0,330,30)
sphere { 0,1 pigment{Red}
translate<7,0,0> rotate z*i }
#end
//---------------------------ground
plane{z,-1
pigment{rgb<0.9,0.8,0.5>}
normal{waves 0.6 scale 0.3 }
}
|
colors.inc textures.inc Woods.inc stones.inc glass.inc metals.inc shapes.inc |
カラー（色名） テクスチャ（総合） テクスチャ（木材） テクスチャ（石材） テクスチャ（ガラス） テクスチャ（金属） 形状 |
#include "colors.inc"
#include "textures.inc"
#include "glass.inc"
|
|
||
#local |
識別子宣言のキーワード | |
| IDENTIFIER | 識別子の名前（40文字以下） | |
| ITEM | 識別子のタイプ。下記のものはすべて識別子として宣言できる。 ●数値、ベクトル、色 ---> 最後にセミコロン(;)を付けることを忘れないこと。 ●文字列表現 ●変形（transform） ●物体（object） ●テクスチャ、ピグメント、法線、フィニッシュ、インテリア、メディア、密度 （texture、pigment、normal、finish、interior、media、density） ●カラーマップ、ピグメントマップ、スロープマップ、ノーマルマップ 、密度マップ (color_map、pigment_map、slope_map、normal_map、density_map） ●カメラ（camera） ●光源（light_source） ●大気（atmosphere） ●霧（fog） ●虹（rainbow） ●天球（sky_sphere） ●変形（transform） |
|
#declare Rows = 5;
#declare Count = Count+1;
#local Here = <1,2,3>;
#declare White = rgb <1,1,1>;
#declare Cyan = color blue 1.0 green 1.0;
#declare Font_Name = "ariel.ttf"
#declare Rod = cylinder {-5*x,5*x,1}
#declare Ring = torus {5,1}
#local Checks = pigment { checker White, Cyan }
#declare Here=<1,2,3>;
#declare Count=0; // 変数の宣言と初期化 Countは 0
union {
object { Rod translate Here*Count }
#declare Count=Count+1; // 再宣言（ここで Countは 1 になる）
object { Rod translate Here*Count }
#declare Count=Count+1; // 再宣言（ここで Countは 2 になる）
object { Rod translate Here*Count }
}
|
|
||
| undef のキーワード | ||
| IDENTIFIER | 無効にしたい識別子の名前 | |
|
|
||
| 非推奨フラグのキーワード | ||
| IDENTIFIER | 非推奨の識別子の名前（キーワードなど） | |
|
|
||
| #fopen のキーワード | ||
| IDENTIFIER | 識別子の名前（40文字以下） | |
| filename | ファイル名（40文字以下） | |
| OPEN_TYPE | ||
|
|
||
| #fclose のキーワード | ||
| FILE_HANDLE_IDENTIFIER |
ファイルの識別子 | |
|
|
||
| #read のキーワード | ||
| FILE_HANDLE_IDENTIFIER |
ファイル識別子 | |
| DATA_IDENTIFIER |
データが読み込まれる識別子。宣言されていない識別子の場合は自動的に #declare で宣言された識別子として生成され、データが読み込まれる。 |
|
#read(Myfile, mystring, myfloat, myvector)
"POV-Ray", -123.55, <1,5,8>
|
|
||
| #write のキーワード | ||
| FILE_HANDLE_IDENTIFIER |
ファイル識別子 | |
| BINARY_WORD_TYPE |
バイナリ出力を設定する場合、次のどれかを選択 uint8：符号なし8ビット整数 sint8：符号付き8ビット整数 uint16be：符号なし16ビットワード uint16le：符号なし16ビットワード sint16be：符号付き16ビットワード sint16le：符号付き16ビットワード sint32be：符号付き32ビットワード sint32le：符号付き32ビットワード （詳しくは英文ドキュメント参照） |
|
| DATA_IDENTIFIER |
データが書き出される識別子。 |
|
#declare Val1 = -123.45;
#declare Vect1 = <1,2,-3>;
#write (MyFile,"\"A quote delimited string\",",Val1,",",Vect1,"\n")
"A quote delimeted string" , -123.45, <1,2,-3>
|
|
||
| デフォルト テクスチャのキーワード | ||
| テクスチャのキーワード ▷「12. テクスチャ1」参照 | ||
| ピグメントの設定 ▷「12.1 ピグメント」参照 | ||
| ノーマルの設定 ▷「12.2 ノーマル」参照 | ||
| フィニッシュの設定 ▷「12.3 フィニッシュ」参照 | ||
#default {
texture {
pigment { rgb <1,0,0> }
normal { bumps 0.3 }
finish { ambient 0.4 }
}
}
例） #default { pigment {...} }
例） sphere { <0,0,0>, 1 texture {} } // デフォルト テクスチャが使用される。
#declare Original_Default = texture {} // POV-Rayの元のデフォルト テクスチャ
#default texture { ... } // デフォルト テクスチャを変更
... // ここでは変更したデフォルト テクスチャ
... // が適用される。
#default {texture {Original_Default}} // 元のデフォルト テクスチャに戻す
|
|
||
| 条件指示のキーワード、CONDの部分には論理値を評価する数値を設定する。結果が0.0であれば否、そうでなければ真と評価される。※ 1e-10程度のきわめて小さい値は0とみなされる。 | ||
| TLUE_ITEM ... | CONDが真のときに解析される部分 | |
FALSE_ITEM ... |
CONDが否のときにFALSE_ITEMか実行される。 ※ #else はオプション |
FALSE_ITEM ... |
CONDが否で、次にCOND1が真のときにFALSE_ITEMが実行される。 ※ #elseif はオプション |
| #end | 条件指示の終了を示すキーワード | |
#declare Which=1;
#if (Which)
box { 0, 1 }
#else
sphere { 0, 1 }
#end
|
|
||
| IDENTIFIER |
識別子 | START |
初期値 | END |
終値 |
| STEP |
繰り返しの増分値、STEPが省略された場合は 1 | |
 |
| 図2.6-2 赤い球の円形配置 |
#for (i, 0, 330, 30)
sphere { 0,1 pigment{Red}
translate<7,0,0> rotate z*i }
#end
|
|
||
| 条件指示のキーワード、VALUEの部分には #case 及び #range と比較する数値を設定する。※ 比較の結果、値の差が 1e-10 以下であれば等しいと見なされる。 | ||
ITEM_n |
VALUE = TEST_nのときに解析される部分 TEST_nにはVALUEと比較する数値を設定する。 | |
ITEM_n |
LOW_n≦VALUE≦HIGH_n のときに解析される部分 LOW_nとHIGH_n にはVALUEと比較する数値を設定する。 | |
| それぞれの#case、#range の終了を示すキーワード | ||
ELSE_ITEM |
すべての #case、#range が否であった場合に解析される部分 ※ #elseはオプションであり、設定されていなければ #end に向かう。 | |
| 条件指示の終了を示すキーワード | ||
#switch (VALUE)
#case (TEST_1)
// VALUE=TEST_1のとき、ここを実行
#break //１番目のcase文の終わり、ここで終了
#case (TEST_2)
// VALUE=TEST_2のとき、ここを実行
#break //２番目の case 文の終わり、ここで終了
#range (LOW_1,HIGH_1)
// VALUE>=LOW_1でかつVALUE<=HIGH_1のとき、ここを実行
#break //１番目の range 文の終わり、ここで終了
#range (LOW_2,HIGH_2)
// VALUE>=LOW_2 でかつ VALUE<=HIGH_2 のとき、ここを実行
#break //２番目の range 文の終わり、ここで終了
#else
// どのケースにもあてはまらないとき、ここを実行
#end // swich文の終わり
|
|
||
| 繰り返しの初期値の設定。C は繰り返しの回数を制御する識別子であり、INITIAL_VALUEには繰り返しの初期値を設定する。 | ||
| 繰り返しのキーワード、#while から #end までを繰り返す。C が END_VALUE より大きくなったところで繰り返しは終了する。 | ||
| ITEM ... | 繰り返す内容 | |
| Cを増加させる宣言。C_INC には C を増加させる式を設定する。 例） #declare C = C + 1 |
||
| #while の強制終了 | ||
| 繰り返しの終了を示すキーワード | ||
 |
| 図2.6-4 #while の使用例 |
#declare R=seed(0);
#declare D=0;
#while(D<8) //--------------------while start
#declare XA=20+(rand(R)-0.5)*30; // XA: random
object{GATE
translate <XA,D*10,0> }
#declare D=D+1;
#end //---------------------while end
//---------------------------- Fig. 2.6-4 #while
#version 3.7
global_settings
{assumed_gamma 2.2}
#include "colors.inc"
#include "textures.inc"
camera{
location<25,-40,60>
sky<0,0,1>
right <-image_width/image_height,0,0>
look_at<30,30,5>
angle 55
}
light_source{<-50,-20,70> color White
parallel point_at 0}
background {rgb<0.6,0.8,1>}
//---------------------------------object
#declare GATE=
union{
box{0,1 scale <2,4,20> }
box{0,1 scale <2,4,20> translate <28,0,0>}
box{0,1 scale <30,4,2> translate <0,0,20>}
texture {New_Penny}
}
//======================================= While loop
#declare R=seed(0);
#declare D=0;
#while(D<8) //--------------------while start
#declare XA=20+(rand(R)-0.5)*30; // XA: random
object{GATE
translate <XA,D*10,0> }
#declare D=D+1;
#end //---------------------while end
//-------------------------------------ground
plane{z,0
pigment{rgb<0.9,1,0.8>*1.2}
normal{crackle 1 scale 5}
}
|
|
||
| マクロのキーワード | ||
| IDENTIFIER |
識別子の名前（40文字以下） | |
| PALAM_IDENT |
コンマや括弧で分けられたパラメータの括弧はパラメータがなくても必要。 | |
| TOKENS… |
マクロの記述部分 | |
| マクロの強制終了 | ||
| マクロの終了 | ||
|
MACRO_IDENTIFIER ( [ACTUAL_PALAM][, ACTUAL_PALAM]… )
|
||
| MACRO_IDENTIFIER |
マクロの識別子 | |
| ACTUAL_PALAM |
識別子や変数などを設定する。 | |
 |
| 図2.7-2 マクロ HOUSE の使用例 |
//=============================== macro define
#macro HOUSE (WW,DD,HH)
union{
box{ <-0.9,-0.9,0> <0.9,0.9,0.7> //------- room
pigment {NewTan*1.2 } }
box{ <-0.91,-0.91,0> <0.91,0.91,0.06>
pigment{rgb 0.8} }
triangle{<-1,-1,0.7>,<1,-1,0.7>,<0,0,1>} //--- roof
triangle{<1,-1,0.7>,<1,1,0.7>,<0,0,1>}
triangle{<1,1,0.7>,<-1,1,0.7>,<0,0,1>}
triangle{<-1,1,0.7>,<-1,-1,0.7>,<0,0,1>}
pigment { MediumGoldenrod*1.2 }
scale <WW,DD,HH> //-------------------size
}
#end
//--------------------------- Fig. 2.7-2 macro
#version 3.7
#include "colors.inc"
#include "textures.inc"
global_settings
{ assumed_gamma 2.2 }
camera{
location<5,-30,15>
sky<0,0,1>
right <-image_width/image_height,0,0>
look_at <-1.5,-8,0>
angle 60
}
light_source{<70,-50,70> White*1.5
parallel point_at 0 }
background{ rgb <0.8,0.9,1>}
//=============================== macro define
#macro HOUSE (WW,DD,HH)
union{
box{ <-0.9,-0.9,0> <0.9,0.9,0.7> //------- room
pigment {NewTan*1.2 } }
box{ <-0.91,-0.91,0> <0.91,0.91,0.06>
pigment{rgb 0.8} }
triangle{<-1,-1,0.7>,<1,-1,0.7>,<0,0,1>} //--- roof
triangle{<1,-1,0.7>,<1,1,0.7>,<0,0,1>}
triangle{<1,1,0.7>,<-1,1,0.7>,<0,0,1>}
triangle{<-1,1,0.7>,<-1,-1,0.7>,<0,0,1>}
pigment { MediumGoldenrod*1.2 }
scale <WW,DD,HH> //-------------------size
}
#end
//============================ place macro HOUSE
object{ HOUSE(5,12,4) translate<-7,-4,0>}
object{ HOUSE(6,8,6) translate<6,3,0>}
object{ HOUSE(4,4,3) translate<5,-14,0>}
//--------------------------ground
plane{z,0
pigment{rgb<0.8,1,0.7>*1}
normal{granite 0.3 scale 1.2}
}